MATH529 L25 
Conformal mappings

Utility functions

Map of Cartesian coordinate lines

CartesianConformalMap[w_,x1_,x2_,y1_,y2_,dx_,dy_,fW_,fH_]:=Module[{xidplts,yidplts,yimplts,ximplts,W,H},
W=fW(x2-x1); H=fH(y2-y1);
xidplts= Show[Table[ParametricPlot[{x,y},{y,y1,y2},PlotStyle->{Red,Thin},Axes->True,PlotRange->{{x1-W,x2+W},{y1-H,y2+H}}],{x,x1,x2,dx}]];
yidplts= Show[Table[ParametricPlot[{x,y},{x,x1,x2},PlotStyle->{Blue,Thin},Axes->True,PlotRange->{{x1-W,x2+W},{y1-H,y2+H}}],{y,y1,y2,dy}]];
ximplts= Show[Table[ParametricPlot[{Re[w[x+I y]],Im[w[x+I y]]},{y,y1,y2},PlotStyle->Red,Axes->True,PlotRange->{{x1-W,x2+W},{y1-H,y2+H}}],{x,x1,x2,dx}]];
yimplts= Show[Table[ParametricPlot[{Re[w[x+I y]],Im[w[x+I y]]},{x,x1,x2},PlotStyle->Blue,Axes->True,PlotRange->{{x1-W,x2+W},{y1-H,y2+H}}],{y,y1,y2,dy}]];
Show[{xidplts,yidplts,ximplts,yimplts},AspectRatio->1]
]

Map of polar  coordinate lines

PolarConformalMap[w_,r1_,r2_,θ1_,θ2_,dr_,dθ_,fW_,fH_]:=Module[{ridplts,θidplts,rimplts,θimplts,W,H,x1,x2,y1,y2},
x1 = -r2; x2=r2; y1=-r2; y2=r2;
W=fW(x2-x1); H=fH(y2-y1);
ridplts= Show[Table[ParametricPlot[{r Cos[θ],r Sin[θ]},{θ,θ1,θ2},PlotStyle->{Red,Thin},Axes->True,PlotRange->{{x1-W,x2+W},{y1-H,y2+H}}],{r,r1,r2,dr}]];
θidplts= Show[Table[ParametricPlot[{r Cos[θ],r Sin[θ]},{r,r1,r2},PlotStyle->{Blue,Thin},Axes->True,PlotRange->{{x1-W,x2+W},{y1-H,y2+H}}],{θ,θ1,θ2,dθ}]];
rimplts= Show[Table[ParametricPlot[{Re[w[r Exp[I θ]]],Im[w[r Exp[I θ]]]},{θ,θ1,θ2},PlotStyle->Red,Axes->True,PlotRange->{{x1-W,x2+W},{y1-H,y2+H}}],{r,r1,r2,dr}]];
θimplts= Show[Table[ParametricPlot[{Re[w[r Exp[I θ]]],Im[w[r Exp[I θ]]]},{r,r1,r2},PlotStyle->Blue,Axes->True,PlotRange->{{x1-W,x2+W},{y1-H,y2+H}}],{θ,θ1,θ2,dθ}]];
Show[{ridplts,θidplts,rimplts,θimplts},AspectRatio->Automatic]
]

Mappings from integer powers

w2[z_]=(z^2); CartesianConformalMap[w2,-1,1,-1,1,.2,.2,2,2]

w4[z_]=(z^3); CartesianConformalMap[w4,-1,1,-1,1,.2,.2,2,2]

Integer roots

w1f2[z_]=(z^(1/2)); CartesianConformalMap[w1f2,-1,1,-1,1,.2,.2,.5,.5]

PolarConformalMap[w1f2,0.1,1,-π,π,.2,.2,.25,.25]

w1f4[z_]=(z^(1/4)); CartesianConformalMap[w1f4,-1,1,-1,1,.2,.2,.5,.5]

PolarConformalMap[w1f4,0.1,1,-π,π,.2,.2,.25,.25]

Joukowski conformal map

wJ[z_]=z+1/z;
PolarConformalMap[wJ,0.1,1.5,0,2π,.2,π/9.,.5,.5]

wJ[z_]=z-δ+(1/(z-δ)); δ = 0.02 Exp[I π/4];
PolarConformalMap[wJ,0.9,1.1,0,2π,.1,π/9.,.5,.1]

Manipulate[PolarConformalMap[(#-ρ (E^(I ϕ))+(1/(#-ρ (E^(I ϕ)))))&,0.999,1.001,0,2π,.001,π/9.,1,1],{{ρ,0.02},0.0,1.0},{{ϕ,-π/4.},-π,π}]

Manipulate[PolarConformalMap[(#-ρ (E^(I ϕ))+(1/(#-ρ (E^(I ϕ)))))&,0.999,1.001,0,2π,.001,π/9.,0.6,0.6],{{ρ,0.3},0.2,0.4},{{ϕ,-1.38},-π/2,-π/4}]

Manipulate[PolarConformalMap[(n b(((((#-ρ (E^(I ϕ))+b))^n)+(((#-ρ (E^(I ϕ))-b))^n))/((((#-ρ (E^(I ϕ))+b))^n)-(((#-ρ (E^(I ϕ))-b))^n))))&,0.999,1.001,0,2π,.001,π/9.,1.5,1.5],{{ρ,0.2},0.1,0.4},{{ϕ,-.8},-π/2,0},{{b,1.2},0.,2},{{n,2.0},1.8,2.2}]