Boundary Locus Method

Definitions

z[θ_,ρ_,σ_]:=((ρ[(E^(I θ))])/(σ[(E^(I θ))]))

BoundaryLocus[ρ_,σ_,t_,c_]:=ParametricPlot[{Re[z[θ,ρ,σ]],Im[z[θ,ρ,σ]]},{θ,0,2π},Frame->True,FrameLabel->{"Re[z]","Im[z]"},PlotLabel->"Boundary locus of " <> t <> " scheme",PlotStyle->{c,Thick},PlotRange->{{-4,2},{-3,3}},GridLines->Automatic,PlotLegends->LineLegend[{c},{t}]]

Examples

Forward Euler

ρEuler[ζ_]=ζ-1; σEuler[ζ_]=1;

BLEuler=BoundaryLocus[ρEuler,σEuler,"forward Euler",Black]

Backward Euler

ρBackEuler[ζ_]=ζ-1; σBackEuler[ζ_]=ζ;

BLBackEuler=BoundaryLocus[ρBackEuler,σBackEuler,"backward Euler",Brown]

Trapezoid

ρTrap[ζ_]=ζ-1; σTrap[ζ_]=(1/2)(ζ+1);

BLTrap=BoundaryLocus[ρTrap,σTrap,"trapezoid",Blue]

Leapfrog

ρLF[ζ_]=(ζ^2)-1; σLF[ζ_]=2ζ;

BLLF=BoundaryLocus[ρLF,σLF,"leap-frog",Yellow]

Adams-Bashforth of order 2

ρAB2[ζ_]=(ζ^2)-ζ; σAB2[ζ_]=(3/2)ζ-(1/2);

BLAB2=BoundaryLocus[ρAB2,σAB2,"second-order Adams-Bashforth",Red]

Adams-Bashforth of order 3

ρAB3[ζ_]=(ζ^3)-(ζ^2); σAB3[ζ_]=(23/12)(ζ^2)-(16/12)ζ+(5/12);

BLAB3=BoundaryLocus[ρAB3,σAB3,"third-order Adams-Bashforth",Green]

Adams-Moulton of order 3

ρAM3[ζ_]=(ζ^3)-(ζ^2); σAM3[ζ_]=(9/24)(ζ^3)+(19/24)(ζ^2)-(5/24)ζ+(1/24);

BLAM3=BoundaryLocus[ρAM3,σAM3,"third-order Adams-Moulton",Pink]

Adams-Bashforth of order 4

ρAB4[ζ_]=(ζ^4)-(ζ^3); σAB4[ζ_]=(55/24)(ζ^3)-(59/24)(ζ^2)+(37/24)ζ-(9/24);

BLAB4=BoundaryLocus[ρAB4,σAB4,"fourth-order Adams-Bashforth",Purple]

Adams-Moulton of order 4

ρAM4[ζ_]=(ζ^4)-(ζ^3); σAM4[ζ_]=(251/720)(ζ^4)+(646/720)(ζ^3)-(264/720)(ζ^2)+(106/720)ζ-(19/720);

BLAM4=BoundaryLocus[ρAM4,σAM4,"fourth-order Adams-Moulton",Orange]

Adams-Bashforth of order 5

ρAB5[ζ_]=(ζ^5)-(ζ^4); σAB5[ζ_]=(1901/720)(ζ^4)-(2774/720)(ζ^3)+(2616/720)(ζ^2)-(1274/720)ζ+(251/720);

BLAB5=BoundaryLocus[ρAB5,σAB5,"fifth-order Adams-Bashforth",Cyan]

Show[{BLEuler,BLBackEuler,BLAB2,BLTrap,BLAB3,BLAM3,BLAB4,BLAM4,BLAB5,BLLF}]